Back to Questions
3.8k
views1
comment
FParsec: Interacting with UserState via getUserState, setUserState and updateUserState
f#

Stephan, or others-

I have read the docmentation regarding parsing with user state. However, it isn't clear to me how to use this for my situation.

I create the following UserState type:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15

type UserState() =

    let mutable _Verb : IVerb = null
    let mutable _Target : ITarget = null

    member this.HasVerb = _Verb <> null
    member this.HasTarget = _Target <> null

    member this.Verb
        with get()  = _Verb
        and set verb = _Verb <- verb

    member this.Target
        with get() = _Target
        and set target = _Target <- target

I then have the following:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

    let identStart c = isAsciiLetter c || c = '_'

    let identContinue c = isAsciiLetter c || isDigit c || c = '_'

    let identOptions = 
        IdentifierOptions(
            isAsciiIdStart = identStart,
            isAsciiIdContinue = identContinue,
            normalization = nf.FormKC,
            normalizeBeforeValidation = true)

    let ident = identifier identOptions

    let lookup (registry : IRegistry<_>, text : string) =
        let result = registry.Find(text)
        result

    let If predicate (parser : Parser<_,_>) : Parser<_,_> = 
        fun stream ->
            let state = stream.State
            let reply = parser stream
            if reply.Status <> Ok || predicate reply.Result then reply
            else
                stream.BacktrackTo(state)

                Reply(Error, NoErrorMessages)

    let verb = ident .>> ws |>> 
        fun text ->
            let registry = manager.GetVerbRegistry()
            let lexeme = lookup(registry, text)
            lexeme

    let pverb = verb |> If (fun lexeme -> lexeme.Count > 0) |>>
        fun lexeme ->
            if lexeme.IsMatched then 
                let us = getUserState   // <-- returns the correct object?
                us.Verb = lexeme        // 'us' says it is a Parser<'a,'a> and not the user state; do I have to pass a parser to it?
                lexeme |> Expr.Verb
            else 
                lexeme |> Expr.Verbs

Do I have to do the same trick you did on the If function where you exposed the stream and the parser? If I am going to be updating variables do you suggest the updateMethod as demonstrated in your code? If so could you please explain what's going on, if not can you explain how to use get and set user state functions?

Thanks,
Scott

.

"Exposing the stream" is not really a "trick". You're just directly using the "lower-level" FParsec API, which sometimes can be the most elegant or readable way to implement a parser.

One issue with your code is that your UserState type is mutable. If you mutate the user state value (instead of replacing the user state value with a new value) FParsec won't be able to restore old values when a parser backtracks. So you might want to use a UserState type like the following instead:

1
2
3
4

type UserState = {
    Verb: IVerb option
    Target: ITarget option  
}

If you wanted to use the higher-level primitives for pverb, you could do something like

1
2
3
4
5
6
7

let pverb =
    verb |> If (fun lexeme -> lexeme.Count > 0)
    >>= fun lexeme ->
            if lexeme.IsMatched then
                updateUserState (fun us ->  {us with Verb = Some lexeme}) >>% Expr.Verb lexeme
            else
                preturn (Expr.Verbs lexeme)

Or you could directly access the stream and user state like here:

1
2
3
4
5
6
7
8

let pverb =
    verb |> If (fun lexeme -> lexeme.Count > 0)
    >>= fun lexeme stream ->
            if lexeme.IsMatched then
                 stream.UserState <- {stream.UserState with Verb = Some lexeme}
                 Reply(Expr.Verb lexeme)
             else
                 Reply(Expr.Verbs lexeme)
By on 8/26/2011 12:20 PM ()

    Topic tags

    IntelliFactory Offices Copyright (c) 2011-2012 IntelliFactory. All rights reserved.
    Home | Products | Consulting | Trainings | Blogs | Jobs | Contact Us | Terms of Use | Privacy Policy | Cookie Policy     		Built with WebSharper