Back to Questions
1.1k
views1
comment
'type unit' error
f#functional

Okay, I feel like I'm asking way too many questions about this stuff. Maybe this is why I shunned functional programming the first time around...I don't like feeling stupid. Anyway.

I'm translating some code that figures out curve paths, and something that seems like it should work doesn't. That's a common theme, isn't it? I keep thinking it should work, but none of it actually does. Here, then, are the five lines that have confounded me for an hour and a half:

1
2
3
4
5

let boundary_ths path ths closed =
    if not closed then
        let first_ths = float(2) * Math.Atan2(path.(1).(1) - path.(0).(1), path.(1).(0) - path.(0).(0)) - (List.nth ths 1);
        let last_ths = float(2) * Math.Atan2(path.(path.GetLength(0) - 1).(1) - path.(path.GetLength(0) - 2).(1), path.(path.GetLength(0) - 1).(0) - path.(path.GetLength(0) - 2).(0)) - (List.nth ths (ths.Length - 2));
        first_ths :: (List.filter (fun s -> [ s ] not ths.Tail) ths.Tail) @ [last_ths]

The last line is giving the error 'This expression has type 'a list but is here used with type unit'. After some research, I've gotten as far as figuring out that type 'unit' is F# lingo for 'line of code'. What the line should be doing is replacing the first and last elements of a list. Actually, that's not entirely accurate. It should be making a new list with the first and last elements replaced. I can't even begin to estimate how long that one line of code took me to figure out.

What have I done wrong, and what assumption of mine is faulty here?

DC

.

"unit" means "line of F# imperative code". If you see the error you saw then it may be an indication that you're mixing up imperative code and functional code.

In your code you're only returning a result from your function on one branch of your if/then/else. If you want your function to return a new array then you want something like this. Note I've replaced you array-of-arrays with array-of-pairs, and added several more "let" bindings to help make your long lines a bit shorter - this is just a matter of taste, as is using "atan2" instead of Math.Atan2. I've also changed the code to return an array rather than a linked list - I'm pretty sure that's what you want. And finally I'm not too sure why you were using "filter" - you can just chop ou tthe array you're interested in using "Array.sub".

1
2
3
4
5
6
7
8
9
10
11
12
13
14

/// Functional version - creates a new "ths" array 

let adjustBoundaries (path:(float*float)[]) (ths:float[]) closed =
    if not closed then
        let x0,y0 = path.[0]
        let x1,y1 = path.[1]
        let xNm2,yNm2 = path.[path.Length-2]
        let xNm1,yNm1 = path.[path.Length-1]
        let adjust dx dy th = 2.0 * atan2 dy dx - th
        let first = adjust (x1-x0) (y1-y0) ths.[1]
        let last = adjust (xNm1-xNm2) (yNm1-yNm2) ths.[ths.Length - 2]
        Array.concat [ [| first |]; Array.sub ths 1 (ths.Length-2); [| last |] ]
    else
        ths
1
2
3
4
5
6
7
8
9
10
11
12
13

/// Imperative version - mutates "ths" in place

let adjustBoundaries(path:(float*float)[]) (ths:float[]) closed =
    if not closed then
        let x0,y0 = path.[0]
        let x1,y1 = path.[1]
        let xNm2,yNm2 = path.[path.Length-2]
        let xNm1,yNm1 = path.[path.Length-1]
        let adjust dx dy th = 2.0 * atan2 dy dx - th
        let first = adjust (x1-x0) (y1-y0) ths.[1]
        let last = adjust (xNm1-xNm2) (yNm1-yNm2) ths.[ths.Length - 2]
        ths.[0] <- first;
        ths.[ths.Length-1] <- last

Regards

don

By on 7/25/2007 3:52 PM ()

    Topic tags

    IntelliFactory Offices Copyright (c) 2011-2012 IntelliFactory. All rights reserved.
    Home | Products | Consulting | Trainings | Blogs | Jobs | Contact Us | Terms of Use | Privacy Policy | Cookie Policy     		Built with WebSharper